There currently are two entry points to execute code in WebSharper. One is the control rendering mechanism. Since control rendering happens after the document has loaded, document "ready" event will not fire at this time. Another mechanism is using let-bound properties in modules, but as of 2.4 that code too executes after "ready" event.

Note that this makes it unnecessary to subscribe to "ready", just fire off your code from controls or modules.

Looking at your code, there are a number of problems with it. First and foremost, please clearly separate client and server code and use IntelliFactory.WebSharper.Html on the client and IntelliFactory.Html on the server. To call into client-side code from the server, use Web.Control control objects. Otherwise you are attempting to call into client-side code directly, which causes failure.

You also need to emit valid JSON (proper quoting) to get the jQuery callback to fire in your example.

Finally I use "OnAfterRender" to attach code to execute after the control has rendered, this is handy in many situations where the code must assume that DOM nodes have been already inserted into the document tree.

namespace Website

open IntelliFactory.WebSharper

type Action =
    | Home
    | About

/// Hello World API client.
type HelloWorldData = { Message : string }

module Client =
    open IntelliFactory.WebSharper.JQuery
    open IntelliFactory.WebSharper.Html

    [<JavaScript>]
    let HelloWorld () =
        Div [Id "message"] -< []
        |>! OnAfterRender (fun self ->
            JQuery.GetJSON("HelloWorld", fun (data,_) ->
                self.Text <- data.Message)
            |> ignore)

[<Sealed>]
type HelloWorldControl() =
    inherit Web.Control()

    [<JavaScript>]
    override this.Body = Client.HelloWorld() :> _

module Server =
    open IntelliFactory.Html
    open IntelliFactory.WebSharper.Sitelets

    /// The hello world api.
    let HelloWorld : Content<Action> =
        CustomContent <| fun ctx ->
            {
                Status = Http.Status.Ok
                Headers = [ Http.Header.Custom "Content-Type" "application/json" ]
                WriteBody = fun stream ->
                    use tw = new System.IO.StreamWriter(stream)
                    tw.WriteLine "{\"Message\": \"hello, world!\"}"
            }
 
    /// A client page for the HelloWorld api.
    let Message : Content<Action> =
        Content.PageContent <| fun ctx ->
            {
                Page.Default with
                    Body =
                        [
                            H1 [Text "Message"]
                            Div [new HelloWorldControl()]
                        ]
            }

    let Main =
        Sitelet.Sum [
            Sitelet.Content "/" Home Message
            Sitelet.Content "/HelloWorld" About HelloWorld
        ]

    type Website() =
        interface IWebsite<Action> with
            member this.Sitelet = Main
            member this.Actions = [Home; About]

    [<assembly: WebsiteAttribute(typeof<Website>)>]
    do ()

JQuery.Of(Dom.Document.Current).Ready(fun _ -> ...)

Div []

Body 
[
    H1 [Text "Message"] :> INode<_>
    new HelloWorldControl() :> _
]